Handling Timer Events—and Creating an Alarm Clock

To get an idea how timers work, I'll create an example alarm clock, called Timers on the CD-ROM. You can see this example at work in Figure 8.7. Here, the user can click the "Start clock" button to start the clock, which is displayed in a label control. (I've set the font of the label at design time to use a large font face, as shown in Figure 8.7.) The clock's display is updated once a second in the timer in this example, Timer1. I've set the timer's Interval property to 1000 milliseconds, or one second, which means its Tick event occurs every second. I update the label's text like this in the Tick event handler: Label1.Text = TimeOfDay (the TimeOfDay property returns a DateTime object with the current time).

The user also can enter a time for the alarm to go off in three text boxes (using 24-hour format; for example 13:00:00 for 1:00:00 P.M.), and click the "Alarm on" radio button to "arm" the alarm clock. When the current time equals or exceeds the alarm time, the clock will beep once a second until the user clicks the "Alarm off" radio button. (These two radio buttons, "Alarm on" and "Alarm off", actually set the state of an internal Boolean variable, blnAlarm, which is True when the alarm is armed and False otherwise.)

Here's the whole code. Note that I'm using three handy properties here—TimeOfDay, which returns a DateTime object holding the current time of day; Today, which returns a DateTime object holding today's date; and Now, which returns a DateTime object that holds both today's time and date:

Public Class Form1
    Inherits System.Windows.Forms.Form

    'Windows Form Designer generated code

    Dim blnAlarm As Boolean = False

    Private Sub Timer1_Tick(ByVal sender As System.Object, _
        ByVal e As System.EventArgs) Handles Timer1.Tick
        Label1.Text = TimeOfDay
        If TextBox1.Text <> "" And TextBox2.Text <> "" And _
            TextBox3.Text <> "" Then
            Dim AlarmTime = New DateTime(Today.Year, Today.Month, _
                 Today.Day, CInt(TextBox1.Text), CInt(TextBox2.Text), _
                 CInt(TextBox3.Text))
            If Now > AlarmTime And blnAlarm Then
                Beep()
            End If
        End If
    End Sub

    Private Sub Button1_Click(ByVal sender As System.Object, _
        ByVal e As System.EventArgs) Handles Button1.Click
        Timer1.Enabled = True
    End Sub

    Private Sub RadioButton1_CheckedChanged(ByVal sender As _
        System.Object, ByVal e As System.EventArgs) _
        Handles RadioButton1.CheckedChanged
        If RadioButton1.Checked Then
            blnAlarm = True
        End If
    End Sub
    Private Sub RadioButton2_CheckedChanged(ByVal sender As _
        System.Object, ByVal e As System.EventArgs) _
        Handles RadioButton2.CheckedChanged
        If RadioButton1.Checked Then
            blnAlarm = False
        End If
    End Sub
End Class

And that's all it takes—you can see the results in Figure 8.7. Now we've created a working alarm clock, using timers.